アセンブリ言語とは（その２）

はじめに課題ありき

「１＋２＋３＋４＋５を GMC-4 上で計算しなさい」

• 演算（「＋」とか「−」とか）は必ずＡレジスタとデータメモリの 間で行われる。つまり、計算する対象のうち一方はあらかじめレジスタに のせておかなくてはならない
• 上に関連して、１度には２つの数しか足したりできない
• さらに言うと加算はＡレジスタしかできないし、Ｙレジスタはデータメ モリのインデックス（指標、要するに今データメモリのどこを使おうとしてい るかを覚えておくところ）としての役割がほぼ決め打ちになっている
• ………など

すると、

1. 最初に１〜５を適当な場所 (50-54) においておいて、
2. 適当なレジスタにまず最初の１(50 の中身）をのっけて、
3. 上のレジスタと、２(51 の中身）を足して、
4. 上のレジスタと、３(52 の中身）を足して、
5. 上のレジスタと、４(53 の中身）を足して、
6. 上のレジスタと、５(54 の中身）を足して、
7. 全部足された上のレジスタの中身を表示する。

  TIY 0
  MA
  TIY 1
  M+
  TIY 2
  M+
  TIY 3
  M+
  TIY 4
  M+
  AO
...
50: 1
51: 2
52: 3
53: 4
54: 5

アルゴリズムということ

元の問題は要するに「１から５までの数を足せ」ということですから、問題を 整理し、要領のよいプログラムを組んでみます。ただし、加算はＡレジスタし かできないし、Ｙレジスタはデータメモリのインデックスですから、作業用レ ジスタはＡでしか有り得ない、だけど、作業領域も必要だし…等の制約がある なかで、かなりの工夫が必要です。

世間に普通に使われている CPU である x86( = Core i, ATOM, ...), ARM, ... は、もっと命令セットが大きい（沢山の命令がある）ので、もっと柔軟に プログラムが組めます。

1. Ａを１にしておきます
2. Ｙを０にして、
   Ａの値をデータメモリ (50 番地）におきます（最初は１）
3. Ｙを１にして、
   Ａの値をデータメモリ (51 番地）におきます（最初は１）
4. ループ：（ラベル＝アドレスに付ける名前、を置いておきます）
   Ｙを１にして、
   データメモリ (51 番地）の値をＡにおきます
5. Ａに１を足します（カウンタのインクリメント）
6. Ａと６と比べて、
   偽なら（５まで足していないので）「中間」へとびます
   そうじゃない＝真なら（５まで既に足したことになるので）「結果の表示部」へとびます
7. 中間：
   Ａの値をデータメモリ (51 番地）におきます
8. Ｙを０にして、
   Ａとデータメモリ 50 番地の値を足して、
   結果（Ａの値）をデータメモリ 50 番地に保存します。
9. 「ループ」に飛びます（繰り返しの意）
10. 結果の表示部：
    Ｙを０にして、
    データメモリ(50 番地）の値をＡにおいて、
    Ａを表示します。
11. 終了：「終了」（自分自身）に飛びます（無限ループ）

	TIA 1
	TIY 0
	AM
	TIY 1
	AM
LOOP:	
	TIY 1
	MA
	AIA 1
	CIA 6
	JUMP MID
	JUMP RESULT
MID:	
	AM
	TIY 0
	M+
	AM
	JUMP LOOP
RESULT:	
	TIY 0
	MA
	AO
END:	
	JUMP END

00:	8 1		TIA 1
02:	A 0		TIY 0
04:	4		AM
05:	A 1		TIY 1
07:	4		AM
08:		LOOP:	
08:	A 1		TIY 1
0A:	5		MA
0B:	9 1		AIA 1
0D:	C 6		CIA 6
0F:	F 1 5		JUMP MID
12:	F 1 D		JUMP RESULT
15:		MID:	
15:	4		AM
16:	A 0		TIY 0
18:	6		M+
19:	4		AM
1A:	F 0 8		JUMP LOOP
1D:		RESULT:	
1D:	A 0		TIY 0
1F:	5		MA
20:	1		AO
21:		END:	
21:	F 2 1		JUMP END